#!/usr/local/bin/perl -w
#
# Original version by Sam Ruby, written in Python.
# Ported to Perl, and enhanced by Jim Jagielski
# Enhanced to have links to personal pages by Sam Ruby.
# Cleaned up, bugfixed and improved a bit by Ask Bjoern Hansen
#
# Usage: ./committers.pl

#  creates the projects.html, committers.html and projects.html which
#  lists the ASF CVS project modules and the committers of those
#  modules. If they are also ASF members, their CVS id and name will
#  be in bold.  This must be run on cvs.apache.org, to read the
#  correct avail and passwd files.

use strict;
use lib '/home/ask/perl/lib';
use LWP::Simple;

#
#  these used to be a "isin" function here.  I changed that to just
#  use a hash in the data. If a array really is needed, then perl does
#  provide the "grep" function.
# 

# populate dictionary fullname from passwd file
my %fullname;
open(PASSWD, '/etc/passwd') or die "Cannot open passwd file: $!\n";
while (my $line = <PASSWD>) {
  chomp $line;
  my ($username, $fullname) = (split ':', $line)[0,4];
  next unless $fullname and $username;
  $fullname{$username} = (split ',', $fullname)[0];
}
close PASSWD;

# Now populate the members array
my %members;
open(MEMBERS, '/etc/group') or die "Cannot open /etc/group file: $!\n";
while (my $line = <MEMBERS>) {
  next unless $line =~ s/^apmember:\*:\d+://;
  chomp $line;
  %members = map {$_, undef} split(/,/, $line);
}
close MEMBERS;

# A fairly liberal regular expression that matches non-relative URLs
my $urlre='[a-zA-Z][\w+\-.]*://[\w;/?:@&=+\$.\-_!~*\'()%,#]+';

# retrieve various lists
my %website;

# Consume Jakarta
my $page = get 'http://jakarta.apache.org/site/whoweare.html' 
  or die "Could not fetch http://jakarta.apache.org/site/whoweare.html";
$page =~ s/\s+/ /g;
while ($page =~ m{<b> ?<a href="($urlre)">([\w ]+)</a> ?</b>}msg) {
  $website{$2} = $1;
}

# Consume httpd
$page = get 'http://httpd.apache.org/contributors/';
while ($page =~ m!.*?<p>(.*?)</p>!gs) {
  my $p = $1;
  next unless $p =~ m/>Name:</;
  my ($unix, $name) = $p =~ m!Name:.*?<a name="(\w+)">(.*?)</a>!;
  my ($url)         = $p =~ m!URL:.*?<a href="($urlre)"!;
  $website{$name} = $website{$unix} = $url if $url;
}

# Consume members
$page = get 'http://www.apache.org/foundation/members.html';
$page =~ s/\xf8/oe/g;   # Ask Bj&oslash;rn Hansen
$page =~ s/\xe1/a/g;      # Wilfredo S&#225;nchez 
$page =~ s/[\s+]/ /gs;      # newlines in the middle of names
while ($page =~ m{<strong>\s*<a href="($urlre)">([\w ]+)</a>\s*</strong>}sg) {
  $website{$2} = $1;
}

#use Data::Dumper;
#print Data::Dumper->Dump([\%website], [qw(website)]);

# populate dictionary module from avail file
# tally stores the CVS modules the user is a member of
my %module;
my %tally;
open(AVAIL, '/home/cvs/CVSROOT/avail') || die "Cannot open avail file\n";
while (my $line = <AVAIL>) {
  chomp $line;
  my @data = split('\|', $line);
  if ($data[0] and $data[0] eq 'avail') {
    foreach my $name (split(',', $data[2])) {
      next unless -d "/home/cvspublic/$name";
      foreach my $id (split(',', $data[1])) {
	$module{$name}->{$id} = 1;
	$module{"cvs-committers"}->{$id} = 1;
        $tally{$id}->{$name} = 1;
      }
    }
  }
}

my %links;
my %fullname_field;
for my $id (sort keys %tally) {
  $fullname{$id} ||= "";   # avoid use of uninitialized variable warning
  $links{$id} = $website{$id} || $website{$fullname{$id}} || "";

  $fullname_field{$id} = $fullname{$id} || '';
  $fullname_field{$id}    = qq[<a href="$links{$id}">$fullname_field{$id}</a>] if $links{$id};
  
}

write_file("projects",   grep { $_ ne "cvs-committers" } sort keys %module );
write_file("committers", grep { $_ eq "cvs-committers" } sort keys %module );
write_file("people");

sub write_file {
    my $iam = shift;
    my @modules = @_;


    my $title = "Apache Committers";
    $title   .= " by Project Modules" if $iam eq "projects";

  open(STDOUT, ">$iam.html.tmp") or die "Cannot open $iam.html.tmp: $!\n";

# Start of the HTML file. The LEFT SIDE NAVIGATION shamelessly
# stolen from the main www.apache.org static pages.

print <<EOF;
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
               "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html>
<head>
 <meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
 <title> $title </title>
</head>
<body bgcolor="#ffffff" text="#000000" link="#525D76">
 <font color="#000000" size="-1" face="verdana,arial,helvetica,sanserif">
 <table border="0" width="100%" cellspacing="0">
  <tr><td align="left" valign="top">
   <a href="http://www.apache.org/"><img src="http://www.apache.org/images/asf_logo_wide.gif" alt="The Apache Software Foundation" align="left" border="0"/></a>
   </td></tr>
   <tr><td><hr noshade="noshade" size="1"></td></tr>
 </table>
 <h1> $title </h1>
 <table cellspacing="4" width="100%" border="0">
  <tr>
   <td colspan="2">
   <hr size="1" noshade="">
   </td>
  </tr>
  <tr>
  <!-- LEFT SIDE NAVIGATION -->
   <td valign="top" nowrap="nowrap">
   <p><b><a href="/foundation/projects.html">Apache Projects</a></b></p>
   <menu compact="compact">
    <li><a href="http://httpd.apache.org/">HTTP Server</a></li>
    <li><a href="http://apr.apache.org/">APR</a></li>
    <li><a href="http://jakarta.apache.org/">Jakarta</a></li>
    <li><a href="http://perl.apache.org/">Perl</a></li>
    <li><a href="http://php.apache.org/">PHP</a></li>
    <li><a href="http://tcl.apache.org/">TCL</a></li>
    <li><a href="http://xml.apache.org/">XML</a></li>
    <li><a href="/foundation/conferences.html">Conferences</a></li>
    <li><a href="/foundation/">Foundation</a></li>
   </menu>
   <p><b><a href="/foundation/">Foundation</a></b></p>
   <menu compact="compact">
    <li><a href="/foundation/faq.html">FAQ</a></li>
    <li><a href="/foundation/roles.html">Management</a></li>
    <li><a href="/foundation/news.html">News &amp; Status</a></li>
    <li><a href="/foundation/press/kit/">Press Kit</a></li>
    <li><a href="/foundation/contact.html">Contact</a></li>
   </menu>
   <p><b>Get Involved</b></p>
   <menu compact="compact">
    <li><a href="/foundation/contributing.html">Contributing</a></li>
    <li><a href="/foundation/mailinglists.html">Mailing Lists</a></li>
    <li><a href="/foundation/cvs.html">CVS Repositories</a></li>
   </menu>
   <p><b>Download</b></p>
   <menu compact="compact">
    <li><a href="http://www.apache.org/dyn/closer.cgi">from a mirror</a></li>
    <li><a href="/dist/">from here</a></li>
   </menu>
   <p><b>Sister Projects</b></p>
   <menu compact="compact">
    <li><a href="http://modules.apache.org/">Module Registry</a></li>
    <li><a href="http://www.apache-ssl.org/">Apache-SSL</a></li>
    <li><a href="http://www.modssl.org/">mod_ssl</a></li>
    <li><a href="http://java.apache.org/">Java-Apache</a></li>
   </menu>
  </td>
  <!-- RIGHT SIDE INFORMATION -->
  <td valign="top" align="left">
EOF

print "<h2>" . ($iam eq "people" ? "Apache Committers" : "Project Modules") . "</h2>";

# create at most a "table" with 5 columns... May need to reduce that
# (making it longer) to avoid VERY wide pages. For now, we just
# reduce the font size one more tic
my $cols = 5;
my $rows = (scalar(@modules) + $cols - 1) / $cols;
print <<EOF;
   <font color="#000000" size="-2" face="verdana,arial,helvetica,sanserif">
   <table border="0">
EOF
for my $row (0..$rows) {
  print "    <tr>\n";
  for my $col (0..$cols) {
    my $name = $modules[$row+$col*$rows];
    if (defined($name)) {
      print "     <td><a href=\"#$name\">$name</a></td>\n";
    }
  }
  print "    </tr>\n";
}
print <<EOF;
   </table>
   </font>
EOF

# The committers page includes an extra table cell, which lists the cvs
# modules they are committers of
my ($header, $listocvs);
if ($iam eq "projects") {
  $header = "<tr><td bgcolor=\"#039acc\">CVS id</td><td bgcolor=\"#039acc\">Name</td></tr>";
  $listocvs = "";
} else {
  $header = "<tr><td bgcolor=\"#039acc\">CVS id</td><td bgcolor=\"#039acc\">Name</td><td bgcolor=\"#039acc\">CVS Projects</td></tr>";
}

    if ($iam eq "people") {
      print q[<table border="0">];
      my $cols = 3;
      my $i    = 0;
      print "<tr>";
      for my $id (sort { lc ($fullname{$a}||$a) cmp lc ($fullname{$b}||$b) } keys %tally) {
	# we could make it skip everyone without a page, but that
	# would just nto be right.
	#next unless $fullname_field{$id} =~ m/href=/;
	print "</tr><tr>" unless $i++ % $cols;
	print "<td>" . ($fullname_field{$id} || $id) . "</td>\n";
      }
      print "<td></td>" while $i++ % $cols;
      print "</tr>";
      print q[</table>];

    }
    else {

# produce a sorted list of committers to each project
print "   <hr size=\"1\" noshade=\"\">\n";
for my $name (@modules) {
  print <<EOF;
   <h2 id="$name">$name</h2>
   <table border="0" width="100%">
    $header
EOF
  for my $id (sort keys %{$module{$name}}) {

    if ($iam ne "projects") {
      $listocvs = "";
      foreach my $cvss (sort keys %{$tally{$id}}) {
        $listocvs .= " $cvss,";
      }
      chop $listocvs;
      $listocvs = qq[<td bgcolor="#a0ddf0">$listocvs</td>];
    }

    # we'll print member names in bold
    my $usernamefield = $id;
    $usernamefield    = "<b>$id</b>" if exists $members{$id};
    my $fullnamefield = $fullname_field{$id} || '&nbsp';
    $fullnamefield    = "<b>$fullnamefield</b>" if exists $members{$id};


    print <<EOF;
     <tr>
      <td bgcolor="#a0ddf0">$usernamefield</td>
      <td bgcolor="#a0ddf0">$fullnamefield</td>
      $listocvs
     </tr>
EOF
  }
  print "   </table>\n";
}

# closing
print <<EOF;
  </td></tr>
 </table>
EOF

}  # not $iam eq people

print <<EOF;
 </font>
</body>
</html>
EOF


close STDOUT;
rename "$iam.html.tmp", "$iam.html" or die "Could not rename $iam.html.tmp to $iam.html: $!";

}

exit;